import caurina.transitions.*;
 
var box1: TextBox = new TextBox(); // TextBox is a symbol in the library
box1.x = 30;
box1.y = 35;
addChild(box1);
 
var box2: TextBox = new TextBox();
box2.x = 270;
box2.y = 35;
addChild(box2);
 
box1.addEventListener(MouseEvent.CLICK, click);
 
function click(e: MouseEvent): void {
  Tweener.addTween(box1, {z: 200, time: 1});
  Tweener.addTween(box1, {z: 0, time: 1, delay: 1});
}

When you click the left text box it will move back and forth to its original position, but after the animation (after using 3D transformation) the text becomes blurry (compare to the text on the right).

When a DisplayObject is started to be transformed in 3D, then its transform.matrix3D property is used instead of transform.matrix, which is used for 2D transformations. If we could switch back to using transform.matrix, the smoothing and its effect would be disappear. After starting to transform an object in 3D it will not switch back automatically to 2D/transform.matrix at any time, so we have to do it manually. When transform.matrix3D is in use, the value of transform.matrix is null, and vice versa if transform.matrix is in use, the value of transform.matrix3D is null. If we nullify any of these properties manually, Flash automatically switches to using the other one (with a default identity matrix). The same effect if we assign a value (a Matrix or Matrix3D reference) to the currently unused property. So the only thing what we need to do is saving the original transform.matrix value before starting 3D transformations and restoring it when we want to switch back to 2D. The example below extends the previous one. It saves the Matrix stored in transform.matrix before starting the 3D animation, and assigns it again when the animation is complete.

import caurina.transitions.*;
 
var box1: TextBox = new TextBox(); // TextBox is a symbol in the library
box1.x = 20;
box1.y = 35;
addChild(box1);
 
var box2: TextBox = new TextBox();
box2.x = 230;
box2.y = 35;
addChild(box2);
 
box1.addEventListener(MouseEvent.CLICK, click);
 
var oldMatrix: Matrix;
 
function click(e: MouseEvent): void {
  // if no tween in progress
  if (!Tweener.isTweening(box1)) {
    oldMatrix = box1.transform.matrix;
    Tweener.addTween(box1, {z: 200, time: 1});
    Tweener.addTween(box1, {z: 0, time: 1, delay: 1, onComplete: tweenComplete});
  }
}
 
function tweenComplete(): void {
  box1.transform.matrix = oldMatrix;
}

We could omit the saving of the old matrix, of course, since assigning null to transform.matrix3D also switches back to 2D, but in this case a new identity matrix will be stored in transform.matrix, so we have to take care of transforming our object to the desired position.

Here is the proof of concept script, which takes a string and creates as many text fields (= columns) as many required to display the whole text. The script can be placed directly on a frame of an empty .fla and it will work. This script is a proof of concept only, it could be wrapped into a nice class for general use, but this work should be done by somebody else (or by me, if I will need it in a real project, but that’s not the case at the moment).

// the text to be displayed in multiple columns
var text: String = "Lorem ipsum dolor sit amet...";
 
// the width of a column in pixels
var columnWidth: Number = 200;
// the height of a column in pixels
var columnHeight: Number = 300;
// the space betweeb columns in pixels
var columnSpacing: Number = 10;
 
// the format of the text in the columns
var tf: TextFormat = new TextFormat();
tf.font = "Arial";
tf.size = 12;
tf.align = "left";
tf.color = 0x000000;
 
// the index of the column currently processed
var colIndex: Number = 0;
// the index of the previous column
var prevColumn: TextField;
// true, if we have placed the last column and can quit the loop
var done: Boolean = false;
 
do {
// create a text field for the current column
var column: TextField = createTextField("column" + colIndex, getNextHighestDepth(), colIndex * (columnWidth + columnSpacing), 0, columnWidth, columnHeight);
// set some properties of the text field
column.border = true;
column.multiline = true;
column.wordWrap = true;
// selectable should be false, otherwise the text field's content will be scrollable,
// and that can mess our precisely positioned text columns
column.selectable = false;
column.setNewTextFormat(tf);
// place the whole text into each column
column.text = text;
// if it is not the first column...
if (prevColumn != null) {
// check whether the last visible line is beyond the last scrollable line, so did we reach
// the last text chunk and the last column or not
if (prevColumn.bottomScroll > prevColumn.maxscroll) {
// calculate how many lines are missing from the last chunk to form a whole column
var missingLines: Number = prevColumn.bottomScroll - prevColumn.maxscroll + colIndex;
// append so many lines to the content of the last column
var s: String = "";
for (var i: Number = 0; i < missingLines; i++)
s += "\n";
column.text += s;
// and quit at the end of the loop, since we reached the last column
done = true;
}
// scroll to the line following the last visible line of the previous column
column.scroll = prevColumn.bottomScroll + 1;
} else {
// in the case of the first column check whether we have the text
// long enough for displaying at least one more column (is the text field scrollable)
if (column.maxscroll <= 1)
done = true
}
prevColumn = column;
colIndex++;
} while (!done);

That’s all – enjoy

Update: I corrected the script according to Mau’s observation. Thank you Mau for catching the bug!

Thanks to Reider for the links

Targeting Flash Player 10 beta and development tools
1. Targeting Flash Player 10 Beta with Flex SDK 3.0.x
2. Flex 3 SDK Downloads – The latest Flex SDK, which is capable of compiling Flash 10 targeted movies. Also includes a stand-alone debug player (version 10)
3. Flash Player 10 support in FlashDevelop
4. How to get started with creating content for Flash Player 10 (video tutorial)

3D, the new Drawing API, GPU acceleration
1. Senocular: Flash Player 10 Drawing API
2. Tinic Uro: What does GPU acceleration mean?
3. How to take ordinary display objects into the third dimension in Astro (video tutorial)
4. Mike Melanson: Flash Uses The GPU

Creating dynamic sounds
1. Tinic Uro: Adobe is making some noise. Part 1
2. Tinic Uro: Adobe is making some noise. Part 2
3. Tinic Uro: Adobe is making some noise. Part 3
4. Keith Peters: Astro dynamic sound!
5. How to dynamically create sounds using the new features in Astro (video tutorial)
6. Leo Bergman: Random thoughts on Vectors and samplesCallbackData

Advanced text rendering
1. New text engine

Loading and saving files without server (FileReference)
1. Load and save files using FileReference
2. How to read and write local files using the new methods of the FileReference class (video tutorial)

Streaming, peer-to-peer audio and video
1. Peer to peer, Speex and UDP now in Flash Player 1
2. Justin Everett-Church: RTMFP in Flash Player 10 beta
3. Justin Everett-Church: Peer to Peer (P2P) in Flash Player 10 beta

Other topics
1. Leo Bergman: Random thoughts on Vectors and samplesCallbackData

Documentation
1. Flash Player 10 (Astro) API (new additions only)
2. Flash Player 10 Language Reference (official Adobe documentation)

The class browser is on-line here.

Maybe I will post the results of my (and other’s) discoveries later with examples Some keywords till then (beyond the features mentioned on Adobe’s site):

• run-time sound generation
• accessing local files through FileReference without uploading to a server
• new Vector class with generics
• etc.

[Update]
Some people reported that the class browser doesn’t worksand the version detection script prevents it from running (claiming a new player installation). I don’t know what does cause the problem, yet, but I provide here a direct link to the SWF itself until I solve the issue:
http://tengerstudio.com/public/flash10/class_browser/ClassBrowser.swf

[Update 2]
I made a minor addition, and the class browser now displays also the class’ constructor among the methods.

http://labs.adobe.com/technologies/flashplayer10/

The development tools are not published yet, but you can configure Flex SDK to compile to Flash Player 10. Here is the how to.

If somebody is not familiar with Flex, it is possible to use Flash CS3 for the same purpose by utilizing some minor hacks. Just follow these steps:

1. Create your Flash movie and write ActionScript with the current development tool (Flash CS3).

2. While writing your ActionScript code take into consideration that the new identifiers, methods and properties will not be recognized by the compiler, so use square brackets where necessary, so instead myObject.propertyName use myObject["propertyName"], and instead myObject.methodName() use myObject["methodName"]().

3. Compile the sources into a SWF file.

4. (This step seems to be optional.) Up to now my SWFs compiled for player 9 were running in Flash Player 10 without any change, and I could use the new features. However it seems possible that setting the target version to 10 is required in some cases, so if you meet such case just change the 4th byte of the SWF file to hexadecimal value 0A (decimal 10 – this byte indicates the target player version) using a hexa editor (e.g.: XVI32).

5. Create an HTML document for embedding your Flash movie. I used SWFObject 2, which is compatible with Flash Player 10, and the embedding HTML looks like this one:

< !DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
 
		<script src="http://blog.tengerstudio.com/wp-admin/swfobject.js" type="text/javascript"><!--mce:0--></script>
		<script type="text/javascript"><!--mce:1--></script>
<div id="myContent">
<h1>Alternative content</h1>
<a href="http://www.adobe.com/go/getflashplayer"><img src="http://www.adobe.com/images/shared/download_buttons/get_flash_player.gif" alt="Get Adobe Flash player" /></a></div>

Replace the parameter values of the embedSWF() method and let’s go. Don’t forget to place swfobject.js into the same directory as the HTML document, and of course install Flash Player 10

Here is a small sample script which uses the new 3D features for creating a rotating object:

var ns: Namespace = new Namespace("http://www.adobe.com/2008/actionscript/Flash10/");
var minZ: Number = 0;
var maxZ: Number = 1000;
var zStep: Number = 10;
 
function enterFrame(aEvent: Event): void {
	logo.ns::rotationY += 1;
	logo.ns::rotationZ += 1;
	logo.ns::z += zStep;
	if (logo.ns::z < minZ || logo.ns::z > maxZ)
		zStep = -zStep;
}
 
addEventListener(Event.ENTER_FRAME, enterFrame);

You can see this sample on-line here. Don’t forget to install Flash Playar 10 to see it in action.

The API documentation of the new player is not available at the moment, so discovering the new features is a must

1
2
3
4
5

var n_num: Number;
trace(getQualifiedClassName(n_num)); // Number
 
var n_int: int;
trace(getQualifiedClassName(n_int)); // int

This outputs the result as expected: Number and int. The uint however seems to be somewhat different. If a value of uint type passed to getClassByName(), one would except that the result will be “uint”, but actually this is not true.

1
2

var n_uint: uint;
trace(getQualifiedClassName(n_uint)); // int

The result is “int” instead of “uint”. Well, that’s not a big surprise, I can imagine that unsigned integers are internally handled by the same class as signed ones. But the situation is more complex, not only uint behaves weird:

1
2
3
4
5
6
7
8

var n_num: Number = 12;
trace(getQualifiedClassName(n_num)); // int
 
var n_int: int = 12;
trace(getQualifiedClassName(n_int)); // int
 
var n_uint: uint = 12;
trace(getQualifiedClassName(n_uint)); // int

If I overwrite the default values and assign the same integer value to all three variables even n_num (of type Number) will be considered as of class int! If I assign a non-integer value to n_num, the result will be Number as expected:

1
2

var n_num: Number = 12.3;
trace(getQualifiedClassName(n_num)); // Number

Does it mean that the class depends on the actual value of the variable? At the first look it seems to be possible, but when I checked whether the class definition (class object) of int and Number are really different, I found that they are not!

1
2
3
4
5
6
7
8
9
10

var n_num: Number = 12.3;
trace(n_num["constructor"]); // [class Number]
 
var n_int: int = 12;
trace(n_int["constructor"]); // [class Number]
 
var n_uint: uint = 12;
trace(n_uint["constructor"]); // [class Number]
 
trace(n_num["constructor"] == n_int["constructor"]); // true

All three numeric types are handled by the same Number class. It doesn’t mean however that both integer and real numbers are handled similarly by the Number class, but their classes are actually the same.

Earlier there was another weird issue with uint, namely that sometimes its type was changed from int to Number and sometimes back from Number to int. This occured with certain values assigned to the variable. I met this issue some times ago, but it seems to be not reproductible now, probably a recent player update corrected the problem. At last I provide here some links where the actual explanation for this issue can be found (see the comments, too) and some general information related to numbers in Actionscript 3 are also collected there:

Ryan Christensen: AS3 Interesting Numeric Storage Behavior
Andre Michelle: Weird behavior of numbers in as3
Michael Baczynski: Bitwise gems – fast integer math
Michael Baczynski: Int, uint and number data type conversion
Sho Kuwamoto: Avoid ints in ActionScript
Grant Skinner: Types in AS3: ints not so fast, uints slow!

The first part of the quoted sentence is true, but the second one is not working. Calling getDefinition() on the child domain will return a reference to the parent’s class instead of the child’s original one. I think this is rather a mistake in the documentation than a player bug, since it seems quite logical: referencing a class by the normal way and through getDefinition() should evaluate to the same value. Anyway, I already posted a small note about that to the online documentation.

1) by opening the namespace and then referring to the desired member:

1
2

use namespace something;
myFunction();

2) by qualifying the method or property with the namespace:

1

something::myFunction();

This is what the documentation says. But in practice when I omit the URI only the first way will work and the second one will not. The compiler passes over, everything seems to be OK, but suddenly my namespaces defined without URI are not found at run-time. E.g. I have a package where I define two namespaces, one without an explicit URI and one with a URI:

first.as

1
2
3

package mypackage {
  public namespace first;
}

second.as

1
2
3

package mypackage {
  public namespace second = "http://tengerstudio.com/namespace/second";
}

And also there is a class using them and defining some methods placed into the above two namespaces:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15

package mypackage {
  public class MyClass {
    first function doSomething(): void {
      trace("doing something");
    }
 
    first function doSomethingElse(): void {
      trace("doing something else 1");
    }
 
    second function doSomethingElse(): void {
      trace("doing something else 2");
    }
  }
}

This all works, yet, so I instantiate this class and try to invoke the doSomething() method:

1
2
3
4
5
6
7

import mypackage.*;
 
var obj: MyClass = new MyClass();
 
use namespace first;
 
obj.doSomething();

This works. But if I use the namespace qualifier, a ReferenceError is thrown:

1
2
3
4
5

import mypackage.*;
 
var obj: MyClass = new MyClass();
 
obj.first::doSomething();

The result is:

ReferenceError: Error #1069: Property mypackage:first::doSomething not found on mypackage.MyClass and there is no default value.
at namespace2_fla::MainTimeline/frame1()

It can be avoided of course if I use the first method, but sometimes it’s not possible, e.g. when there are two or more identical identifiers in different namespaces (as in the case of the doSomethingElse() methods in MyClass) and I want to use all of them.

1
2
3
4
5
6
7
8
9

import mypackage.*;
 
var obj: MyClass = new MyClass();
 
use namespace first;
obj.doSomethingElse();
 
use namespace second;
obj.doSomethingElse();

It will result in a compiler error saying that the reference to doSomething() is ambiguous (of course). But when I try to avoid this and specify exact namespaces:

1
2
3
4
5
6
7

import mypackage.*;
 
var obj: MyClass = new MyClass();
 
obj.first::doSomethingElse();
 
obj.second::doSomethingElse();

I get a run-time error:

ReferenceError: Error #1069: Property mypackage:first::doSomething not found on mypackage.MyClass and there is no default value.
at namespace2_fla::MainTimeline/frame1()

The result is the same when I include the use namespace statement. If I don’t refer to namespace first (which has no associated URI), there is no error, namespace second is working (which has a URI), and if I add a URI to namespace first it will run perfectly, too:

1
2
3

package mypackage {
  public namespace first = "http://tengerstudio.com/namespace/first";
}

What is the conclusion? Never forget to associate a URI with a namespace, even if the documentation says that this is optional.

Well, beside the above ones I mention one more thing related to namespaces, which was not evident to me, but finally I figured out how to use it. This is accessing a namespace defined in a class rather than in a package:

1
2
3
4
5
6
7
8
9
10
11

package mypackage {
 
  public class MyClass2 {
 
    public namespace third = "http://tengerstudio.com/namespace/third";
 
    third function foo(): void {
      trace("foo");
    }
  }
}

The only way I could access and use what is in namespace third was placing it’s value into a variable and referring to the members through this variable:

1
2
3
4
5
6
7

import mypackage.*;
 
var obj: MyClass2 = new MyClass2();
 
var ns: Namespace = MyClass2.third;
 
obj.ns::foo();

So it seems that namespaces defined in a class are always static members, although the static attribute is not allowed on namespace definitions (it throws a compiler error). No other ways worked for me including these ones:

// 1
obj.third::foo();

// 2
obj.(MyClass2.third)::foo();

// 3
use namespace MyClass2.third;
obj.third::foo();

// 4
var ns: Namespace = MyClass.third;
use namespace ns;
obj.foo();

What is also interesting, that I can omit the URI at the definition of namespace third and it will work through the variable reference, so only package level namespaces require URI for using them as direct qualifiers.